Define coordonnées()=
Prgm
:Local r,n,dst
:Local ld,clt,hr,mnh,mn,sc
:Local lod,lom,los,lad,lam,las
:6378→r:0→n:0→dst
:0→ld:0→clt:0→hr:0→mnh:0→mn:0→sc
:0→lod:0→lom:0→los:0→lad:0→lam:0→las
:setMode(5,2)
:©-----------------------explique
:Disp ""
:Disp "L'écart horaire de longitude"
:Disp "Circonférence de la terre à la latitude"
:For i,1,2:Disp "":EndFor
:Disp "       [enter] pour entrer vos coordonnées"
:getKey(1)
:©----------------------Entrée DMS
:Request "Long Degrés = °",lod
:Request "Long Minutes = '",lom
:Request "Long Seconde = """,los
:Request "Lat Degrés = °",lad
:Request "Lat Minutes = '",lam
:Request "Lat Seconde = """,las
:©----------------------Ctrôle DMS
:While lod>180 or lom>60 or los>60
:  If lod>180:lod-180→lod
:  If lom>60:lom-60→lom
:  If los>60:los-60→los
:EndWhile
:While lad>90 or lam>60 or las>60
:  If lad>90:lad-90→lad
:  If lam>60:lam-60→lam
:  If las>60:las-60→las
:EndWhile
:©----------------------Calc Temps
:lod*4→mnh
:((mnh)/(60))→hr
:fPart(hr)*60→mnh
:iPart(hr)→hr
:((lom)/(15))→mn
:round(mn,0)→mn
:mnh+mn→mn
:((los)/(15))→sc
:round(sc,2)→sc
:©----------------------lat décimale
:((las)/(60))→n
:lam+n→n
:((n)/(60))→n
:lad+n→ld
:round(ld,4)→ld
:©-----circonférence de la terre à la latitude
:2*π*cos(ld)*r→clt
:round(clt,3)→clt
:©----------------------Sortie
:For i,1,2:Disp "":EndFor
:Disp "décal. horaire en long. ",hr,"hr ",mn,"min ",sc,"sec"
:Disp ""
:Disp "lat. en degrés décimaux ",ld
:Disp "circ. de la terre à la latitude ",clt
:Disp ""
:Disp "                                  Entrer pour sortir !"
:getKey(1)
:Lbl fin
:EndPrgm